home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / ENTERPRS / C128 / TERMS / BTP12822.SFX / .img strip (.txt) next >
Commodore BASIC  |  1990-02-12  |  2KB  |  54 lines
  1. 0 REM W. ANTHONY MARSH, BCS/CUG, 5/25/86
  2. 1 FORI=1TO255:CLOSEI:NEXT
  3. 5 PRINT"[147]             .IMG STRIPPER              "
  4. 10 PRINT"INSERT DISK, THEN PRESS RETURN[146]." :WAIT 203,1:REM C64 KEYPRESS MATRIX
  5. 15 OPEN15,8,15,"I0":INPUT#15,E,E$,T,S:IFE<20THEN 30
  6. 20 PRINT"DISK ERROR#"E"("E$")":PRINT"AT TRACK"T", SECTOR"S
  7. 25 PRINT"CHECK DISK AND DRIVE. [208]RESS RETURN[146] WHEN READY.":WAIT 203,1:RUN
  8. 30 PRINT"ENTER FILENAME WITH EXACT SYNTAX; DON'T USE WILCARDS SUCH AS * OR ?"
  9. 32 F$="":POKE198,0:INPUT"FILENAME.IMG";F$
  10. 35 OPEN8,8,0,"$0:"+F$
  11. 41 A$="":FORI=1TO32:GOSUB256
  12. 42 A$=A$+D$:NEXT
  13. 43 B$="":FORI=1TO32:GOSUB256
  14. 44 B$=B$+D$:NEXT
  15. 45 C$="":FORI=1TO4:GOSUB256
  16. 46 C$=C$+D$:NEXT
  17. 47 LOW=ASC(MID$(B$,3,1)):HIGH=ASC(MID$(B$,4,1)):B=LOW+256*HIGH
  18. 48 LOW=ASC(MID$(C$,3,1)):HIGH=ASC(MID$(C$,4,1)):C=LOW+256*HIGH
  19. 49 IFC=3341THENPRINTF$" IS NOT ON THIS DISK.":PRINT"CHECK SPELLING.":E=62
  20. 50 IFB>C THEN PRINT"***NOT ENOUGH BLOCKS LEFT TO WRITE FILE.":E=72
  21. 55 CLOSE8:IF E>19 THEN 25
  22. 60 F=LEN(F$):IFRIGHT$(F$,4)=".IMG"THEN70
  23. 61 PRINTF$" DOES NOT APPEAR TO BE AN .IMG FILE."
  24. 62 INPUT"DO YOU WANT TO GO AHEAD ANYWAY  Y[157][157][157]";Y$
  25. 63 IF Y$="Y" OR Y$="[217]" THEN 65
  26. 64 PRINT"***TRANSLATION ABORTED.":END
  27. 65 IF F=0 THEN END
  28. 66 IF F<16 THENOF$=F$+"."
  29. 67 IF F=16 THENOF$=LEFT$(F$,15)+"."
  30. 68 GOTO75
  31. 70 OF$=LEFT$(F$,F-4)
  32. 75 OPEN8,8,8,"0:"+F$
  33. 77 GOSUB256:LOW=ASC(D$):GOSUB256:HIGH=ASC(D$):RANGE=LOW+256*HIGH
  34. 80 I=1:GOSUB 256:A$=D$
  35. 81 I=2:GOSUB 256:B$=D$
  36. 82 I=3:GOSUB 256:C$=D$
  37. 83 I=4:GOSUB 256:TYPE$=D$
  38. 84 IF A$="C"THEN IF B$="C" THEN IF C$="3" THEN 90
  39. 85 TYPE$="S"
  40. 86 IF RANGE=4 THEN 90
  41. 87 IF RANGE<>4 THEN CLOSE8:PRINT".IMG HEADER NOT FOUND.":END
  42. 88 FOR J=5 TO RANGE :GOSUB256:NEXT
  43. 90 OPEN9,8,9,"0:"+OF$+","+TYPE$+",W"
  44. 95 INPUT#15,E,E$,T,S:IF E>19THEN CLOSE8:CLOSE9:GOTO20
  45. 100 FORI=728 TO 767:READ D:POKEI,D:NEXT
  46. 105 SYS 728 :END
  47. 110 DATA 162,  8, 32,198,255, 32,207,255
  48. 115 DATA  72,164,144,162,  9, 32,201,255
  49. 120 DATA 104, 32,210,255,192,  0,240,232
  50. 125 DATA 169,  8, 32,195,255,169,  9, 32
  51. 130 DATA 195,255, 32,204,255, 76,204,255
  52. 256 GET#8,D$:IF D$="" THEN D$=CHR$(0)
  53. 257 RETURN
  54.